Merge branch 'devel-contr-prin-transient' into 'master'

Add new file; main dgibi code to calculate the principal stresses in transient method

See merge request !1

Transient Hygroscopic Stress Codes/contr_prin_transient_domaine_X.dgibi

+********** INPUTS **********
+
+OPTI 'ACQU' 'inputdatbatch.txt';
+ACQU NR1*'ENTIER';
+ACQU NR2*'ENTIER' 
+	 C0*'FLOTTANT' CFIN*'FLOTTANT' NDAY*'FLOTTANT'
+	 DEX*'FLOTTANT' DIN*'FLOTTANT' PML*'FLOTTANT' NUMP*'ENTIER';
+
+********** PART 1 - MAILLAGE **********
+
+'OPTI' DIME 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'TRI3';
+
+'COMM' en mm diametre exterieure;
+DEXT			= (DEX*1.E-3);
+'COMM' en mm diametere interieure;
+DINT			= (DIN*1.E-3);
+PML				= -1*PML;
+
+'COMM' Faire les points;
+REXT	= DEXT/2; 'COMM' Rayon exterieure;
+RINT	= DINT/2; 'COMM' Rayon interieure;
+PCEN	= 0. 0.;
+PMOEL   = (PML*1.E-3) 0.; 'COMM' point coordonne de moelle;
+P1		= (-1*REXT) 0.;
+P2		= 0. REXT;
+P3		= REXT 0.;
+P4		= 0. (-1*REXT);
+P5		= (-1*RINT) 0.;
+P6		= 0. (-1*RINT);
+P7		= RINT 0.;
+P8		= 0. RINT;
+
+'COMM' Faire les lignes;
+NCEXT	= 55;
+NCINT	= 25;
+
+C12		= 'CERC' NCEXT P1 PCEN P2;
+C23		= 'CERC' NCEXT P2 PCEN P3;
+C34		= 'CERC' NCEXT P3 PCEN P4;
+C41		= 'CERC' NCEXT P4 PCEN P1;
+CEXT	= C12 ET C23 ET C34 ET C41;
+C56		= 'CERC' NCINT P5 PCEN P6;
+C67		= 'CERC' NCINT P6 PCEN P7;
+C78		= 'CERC' NCINT P7 PCEN P8;
+C85		= 'CERC' NCINT P8 PCEN P5;
+CINT	= C56 ET C67 ET C78 ET C85;
+
+SUL		= 'SURF' (CEXT ET CINT);
+'ELIM' SUL 1.E-9; 'COMM' Eliminer double noeuds;
+SU		= 'REGE' SUL; 'COMM' Regenerer le maillage;
+
+'COMM' Recuperer le maillage;
+CSU		= 'CONT' SU;
+
+'COMM' PART 2 - MATERIEL;
+
+'COMM' Diffusion properties;
+'COMM' Direction: radial;
+DCOEF1		= 2.04E-11;
+'COMM' Direction: tangentiel;
+DCOEF2		= 1.54E-11;
+CAPAMAT 	= 100.;
+RHOMAT		= 1300.;
+KCOEF1		= DCOEF1*CAPAMAT*RHOMAT;
+KCOEF2		= DCOEF2*CAPAMAT*RHOMAT;
+
+'COMM' Mechanical properties;
+'COMM' Toutes sont en Pa dont kg.m-2;
+'COMM' 1 Radial, 2 Tangential, 3 Longitudinal;
+EMAT1	= 5.1E+09;
+EMAT2	= 4.1E+09;
+EMAT3	= 1.6E+10;
+NUMAT12	= 4.2E-01;
+NUMAT23	= 1.6E-01;
+NUMAT13	= 1.7E-01;
+GMAT12	= 1.8E+09;
+ALPMAT1	= 2.0E-01;
+ALPMAT2	= 3.5E-01;
+   				 
+'COMM' PART 3 - MODELE;
+
+MOD		= 	MODE SU 'THERMIQUE' 'ORTHOTROPE' ;
+MAD		= 	MATE MOD 'RADIAL' PMOEL
+			'K1' KCOEF1 'K2' KCOEF2 'C' CAPAMAT 'RHO' RHOMAT;
+			  			
+MOM = 'MODE' SU 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE';
+MAM = 'MATE' MOM 'RADIAL' PMOEL
+      'YG1' EMAT1 'YG2' EMAT2 'YG3' EMAT3 
+      'NU12' NUMAT12 'NU23' NUMAT23 'NU13' NUMAT13 
+      'G12' GMAT12
+      'ALP1' ALPMAT1 'ALP2' ALPMAT2;
+
+'COMM' PART 4 - CHARGEMENTS;
+
+'COMM' Chargements sur la teneur en eau diffusee;
+BEXT		= 'BLOQ' CEXT 'T';
+BINT		= 'BLOQ' CINT 'T';
+FLT1		= 'DEPI' BEXT CFIN;
+FLT2		= 'DEPI' BINT CFIN;
+TPSFIN		= 86400*NDAY;
+TSTEP		= TPSFIN*0.01; 'COMM' steps in time;
+
+LIST1		= PROG 0. TSTEP TPSFIN;
+LIST2		= PROG (C0/CFIN) 1. 1.;
+EVT1		= EVOL 'MANU' LIST1 LIST2;
+CHT1		= CHAR 'TIMP' FLT1 EVT1;
+CHT2		= CHAR 'TIMP' FLT2 EVT1;
+CHT			= CHT1 ET CHT2;
+C_INI		= MANU 'CHPO' 1 SU 'T' C0;
+
+'COMM' Constraints on displacements;
+PLEFT		= SU POIN 'PROC' (-1*REXT 0.);
+PRIGHT		= SU POIN 'PROC' (REXT 0.);
+PUP			= SU POIN 'PROC' (0. REXT);
+PDOWN		= SU POIN 'PROC' (0. (-1*REXT));
+BLM1		= BLOQ PLEFT 'UX' 'UY'; 'COMM' Blocking the left side;
+BLM2		= BLOQ PRIGHT 'UY';	'COMM' Blocking to prevent rotation;
+
+'COMM' PART 5 - PASAPAS;
+
+TAB1							= TABL;
+TAB1 . 'MODELE'					= MOD ET MOM;
+TAB1 . 'CARACTERISTIQUES'		= MAD ET MAM;
+TAB1 . 'BLOCAGES_THERMIQUES'	= BEXT ET BINT;
+TAB1 . 'BLOCAGES_MECANIQUES' 	= BLM1 ET BLM2;
+TAB1 . 'CHARGEMENT'				= CHT;
+TAB1 . 'TEMPS_CALCULES'			= PROG 0. 'PAS' TSTEP TPSFIN;
+TAB1 . 'TEMPERATURES'			= TABL;
+TAB1 . 'TEMPERATURES' . 0 		= C_INI;
+*TAB1 . 'TALPHA_REFERENCE'		= CFIN;
+*TAB1 . 'TEMPERATURE_REFERENCE'	= C0;
+*TAB1 . 'PROCEDURE_CHARTHER'     = VRAI;
+
+PASAPAS TAB1;
+
+'COMM' PART 6 - POSTPROCESS;
+
+'COMM' Contrainte;
+ND			= DIME (TAB1 . 'DEPLACEMENTS');
+
+REPE BLOC1 ND;
+
+TT			= TAB1 . 'TEMPERATURES' . (&BLOC1-1);
+UT			= TAB1 . 'DEPLACEMENTS' . (&BLOC1-1);
+DELTA_H		= TT-C_INI;
+EPT			= 'EPTH' DELTA_H MOM MAM;
+SIT			= 'ELAS' EPT MOM MAM;
+FFT			= 'BSIG' SIT MOM;
+EP 			= 'EPSI' UT MOM;
+EPE			= EP-EPT;
+SIGUT		= 'ELAS' EPE MOM MAM;
+SIGUTP		= 'PRIN' SIGUT MOM;
+SI11B		= 'NOMC' ('EXCO' SIGUTP 'SI11') 'SI11';
+SI11C		= CHAN 'CHPO' SI11B MOM;
+SI22B		= 'NOMC' ('EXCO' SIGUTP 'SI22') 'SI22';
+SI22C		= CHAN 'CHPO' SI22B MOM;
+
+TITRS11		= CHAI 'SI11FIN_' ((ENTI PML)*-1);
+TITRS22		= CHAI 'SI22FIN_' ((ENTI PML)*-1);
+
+'OPTI' 'SORT' TITRS11;
+'SORT' 'VTK' SU '$try' SI11C . 'SI11' 
+	'TEMP' TAB1 . TEMPS . (&BLOC1-1)
+	'FORM';
+	
+'OPTI' 'SORT' TITRS22;
+'SORT' 'VTK' SU '$try' SI22C . 'SI22' 
+	'TEMP' TAB1 . TEMPS . (&BLOC1-1)
+	'FORM';
+
+FIN BLOC1;
+
+'COMM' Move the stresses to a folder;
+
+COMMAND1 = CHAIN 'rm -rf VTK_stressprin_plancont_temps_domaineX_' NUMP;
+COMMAND2 = CHAIN 'mkdir VTK_stressprin_plancont_temps_domaineX_' NUMP;
+COMMAND3 = CHAIN 'move *pvd VTK_stressprin_plancont_temps_domaineX_' NUMP '/';
+COMMAND4 = CHAIN 'move *vtu VTK_stressprin_plancont_temps_domaineX_' NUMP '/';
+COMMAND5 = CHAIN 'move *trace VTK_stressprin_plancont_temps_domaineX_' NUMP '/';
+
+TAB_VTK = 'EXTE' COMMAND1;
+TAB_VTK = 'EXTE' COMMAND2;
+TAB_VTK = 'EXTE' COMMAND3;
+TAB_VTK = 'EXTE' COMMAND4;
+TAB_VTK = 'EXTE' COMMAND5;
+
+*FIN;
\ No newline at end of file

Transient Hygroscopic Stress Codes/inputdatbatch.txt

+1 Cini Cfin Nday Dext Dint Pmoel Nump
+2 0.085 0.053 52 35 12 60 3